home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Loadstar 6
/
006.d81
/
typing tutor
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-08-26
|
6KB
|
242 lines
1 rem *** typing tutor
2 rem *** by eugene d. kelly, jr.
3 rem *** translated for the 64 by
4 rem *** donna k. woody
5 poke53281,15:poke53280,11:printchr$(144):poke783,peek(783)and254
6 printchr$(147):print:printtab(14)"************":printtab(14)"typing tutor"
7 printtab(14)"************":printtab(19)"by"
8 printtab(10)"eugene d. kelly jr."
9 printtab(5)"translated for the commodore by"
10 printtab(14)"donna k. woody[144]"
11 poke781,22:poke782,7:sys65520:print"press [129]space bar[144] to continue."
12 poke198,0:wait198,1:geta$
20 printchr$(147):printtab(14)"typing tutor"
30 print:print
50 a$="fjdksla: frtgbvjuyhnmeci,wxo.qzp/1029384756"
60 poke781,3:poke782,18:sys65520:print"menu"
70 print"1. home keys lesson"
72 print:print"2. first finger lesson"
74 print:print"3. second finger lesson"
76 print:print"4. third finger lesson"
78 print:print"5. fourth finger lesson"
82 print:print"6. number lesson"
84 print:print"7. quit"
90 poke781,21:poke782,0:sys65520:print"what is your choice 1-7? ";
91 poke198,0:wait198,1:getch$
92 ch=val(ch$)
93 ifch<1orch>7thenprint"please enter a number between 1 and 7.":goto90
94 printchr$(147)
95 onchgosub100,200,300,400,500,600,97
96 goto20
97 print"[147]load"chr$(34)"payload"chr$(34)",8":print"run"
98 poke631,13:poke632,13:poke198,2:end
100 rem home keys gosubs
110 gosub2000
120 gosub3000
130 nc=10:gosub1000
190 return
199 :
200 rem first finger gosubs
210 gosub3000:gosub6000:rem reviews
220 gosub4000:rem first finger exercises
230 nc=22:gosub1000:rem random letters
240 gosub5000:rem word practice
290 return
299 :
300 rem second finger gosubs
310 gosub6100:gosub6120:rem reviews
320 gosub7000:rem second finger exercises
330 gosub5200:rem review words
340 gosub5600:rem second finger words
350 nc=26:gosub1000:rem random letters
390 return
399 :
400 rem third finger gosubs
410 gosub6100:gosub6140:rem reviews
420 gosub7040:rem more reviews
430 gosub8000:rem third finger exercises
440 gosub5200:gosub5600:rem word reviews
450 gosub5700:rem third finger words
460 nc=30:gosub1000:rem random letters
490 return
499 :
500 rem fifth finger gosubs
510 gosub6100:gosub6140:rem reviews
520 gosub7040:gosub8040:rem more reviews
530 gosub9000:rem fourth finger exercises
540 gosub5200:gosub5600:gosub5700:rem word reviews
550 gosub5800:rem fourth finger words
560 nc=34:gosub1000:rem random letters
590 return
599 :
600 printchr$(147):poke781,2:poke782,12:sys65520:print"number lesson"
610 gosub6100:gosub6140:rem reviews
620 gosub7040:gosub8040:gosub9040:rem more reviews
630 gosub9500:rem number exercises
650 gosub5800:rem fourth finger words
660 gosub5900:rem number word
670 nc=44:gosub1000:rem random letters and numbers
690 return
699 :
1000 printchr$(147)
1010 print"one moment, please..."
1015 t$="":flag=2
1020 fori=1to39
1030 n1=n
1040 n=int(nc*rnd(1))+1
1045 ifn1=0then1060
1050 ifmid$(a$,n,1)=mid$(a$,n1,1)then1040
1060 t$=t$+mid$(a$,n,1)
1070 next
1080 poke781,6:poke782,0:sys65520:printt$
1082 ti$="000000"
1083 m=0:c$=""
1088 poke781,9:poke782,0:sys65520:print"copy the above line."
1090 print:print:print
1092 poke204,0:poke207,0:poke198,0:wait198,1:getz$:poke204,1
1093 ifz$=chr$(20)thenprintz$;:c$=left$(c$,len(c$)-1):goto1092
1095 ifz$=chr$(13)thengoto1100
1096 printz$;
1097 c$=c$+z$
1098 goto1092
1100 forx=1tolen(t$)-1
1110 ifmid$(c$,x,1)=mid$(t$,x,1)thenm=m+1
1120 next
1230 print:print:print:print" you did "m" letters correct out of"
1240 printlen(t$)-1" in "mid$(ti$,3,2)":"right$(ti$,2)" seconds"
1250 poke781,23:poke782,8:sys65520:print"to continue press <return> ";
1260 poke198,0:wait198,1:getz$
1265 ifflag=2and(len(t$)-1-m)>3thengoto1000
1270 flag=0:return
1999 :
2000 print:fork=1to7step2
2010 la$=mid$(a$,k,1):l1$=la$+la$+" "
2020 lb$=mid$(a$,k+1,1):l2$=lb$+lb$+" "
2030 t$=""
2040 forj=1to6
2050 t$=t$+l1$+l2$
2060 next
2070 gosub10000:printchr$(147)
2080 next
2090 return
2999 :
3000 t$=""
3010 fori=1to8
3020 fork=1to2
3030 t$=t$+mid$(a$,i,1)
3040 nextk
3050 t$=t$+" "
3060 nexti
3070 fori=1to8
3080 t$=t$+mid$(a$,i,1)+" "
3090 next
3100 gosub10000
3110 return
3999 :
4000 t$=""
4020 forj=12to16
4030 t1$=t1$+"f"+mid$(a$,j,1)
4035 nextj:t1$=t1$+" "
4040 t$=t1$+t1$+t1$
4050 gosub10000
4100 t$=""
4120 forj=18to22
4130 t2$=t2$+"j"+mid$(a$,j,1)
4135 nextj:t2$=t2$+" "
4140 t$=t2$+t2$+t2$
4150 gosub10000
4200 t$=t1$+t2$+t1$
4210 gosub10000
4300 t$=t2$+t1$+t2$
4310 gosub10000
4400 nc=22
4900 return
4999 :
5000 t$="a fad: as a lad: all ads: fall "
5010 gosub10000
5200 t$="fur fur fun fun far far fan fan fab fab "
5210 gosub10000
5300 t$="gun gun gum gum guy guy gal gal gus gus "
5310 gosub10000
5400 t$="buy buy but but bat bat bag bag bun bun "
5410 gosub10000
5500 t$="hut hut jut jut van van had had has has "
5510 gosub10000
5520 return
5600 t$="jim jim dim dim kid kid red red cue cue "
5610 gosub10000
5620 t$="my: my: fed fed lid lid cut cut aid aid "
5630 gosub10000
5690 return
5700 t$="lot lot sit sit wet wet tex tex co. co. "
5710 gosub10000
5720 t$="sat sat sod sod law law sax sax wax wax "
5730 gosub10000
5790 return
5800 t$="fat fat pat pat zip zip qt. qt. zap zap "
5810 gosub10000
5820 t$="que que pal pal bop bop y/n y/n has has "
5830 gosub10000
5890 return
5900 t$="list 5679 run 2841 9045 s. 8 th street "
5910 gosub10000
5920 t$="try 1084 times 35876 west 165 th blvd. "
5930 gosub10000
5999 return
6000 t$="fd fs fa jk jl j: fd jk fs jl fa j: "
6010 gosub10000
6100 t$="fjdksla: :alskdjf jfkdls:a a:sldkfj "
6110 gosub10000
6111 return
6120 t$="frf ftf fgf fbf fvf juj jyj jhj jnj jmj "
6130 gosub10000
6140 t$="frf juj ftf jyj fgf jhj fbf jnj fvf jmj "
6150 gosub10000
6900 return
6990 return
7000 t$="ded ded dcd dcd kik kik k,k k,k "
7010 gosub10000
7020 t$="ded kik dcd k,k ded kik dcd k,k "
7030 gosub10000
7040 t$="dedcd kik,k dedcd kik,k dedcd kik,k "
7050 gosub10000
7100 return
8000 t$="sws sws sxs sxs lol lol l.l l.l "
8010 gosub10000
8020 t$="sws lol sxs l.l sws lol sxs l.l "
8030 gosub10000
8040 t$="swsxs lol.l swsxs lol.l swsxs lol.l "
8050 gosub10000
8100 return
9000 t$="aqa aqa aza aza :p: :p: :/: :/: "
9010 gosub10000
9020 t$="aqa :p: aza :/: aqa :p: aza :/: "
9030 gosub10000
9040 t$="aqaza :p:/: aqaza :p:/: aqaza :p:/: "
9050 gosub10000
9100 return
9500 t$="f4f f5f j7j j6j f4f f5f j6j "
9510 gosub10000
9520 t$="f4f5f j7j6j f4f5f j7j6j f4f5f j6j7j "
9525 gosub10000
9530 t$="f4f j7j f5f j6j f4f j7j f5f j7j "
9535 gosub10000
9540 t$="d3d k8k d3d k8k d3d k8k d3d k8k "
9545 gosub10000
9550 t$="s2s l9l s2s l9l s2s l9l s2s l9l "
9555 gosub10000
9560 t$="a1a :0: a1a :0: a1a :0: a1a :0: "
9565 gosub10000
9599 return
10000 printchr$(147):poke781,6:poke782,0:sys65520:printt$
10002 gosub1082
10004 if(len(t$)-1-m)<3then10160
10010 printchr$(147):print"you missed "len(t$)-m-1" letters in that"
10020 print"lesson. you'd better try it again."
10030 poke781,22:poke782,8:sys65520:print"press <return> to continue.";
10040 poke198,0:wait198,1:getz$:printchr$(147):goto10000
10160 return
63000 rem link back
63010 print"[147]load"chr$(34)"payload"chr$(34)",8":print"run"
63020 poke198,0:poke631,13:poke632,13:poke198,2:end